webdevqa.jp.net

VBAコードの実行時間をどのようにテストしますか?

VBAにコードがありますか?関数をラップして実行にかかった時間を知らせて、関数の異なる実行時間を比較できますか?

90
Lance Roberts

関数が非常に遅い場合を除き、非常に高解像度のタイマーが必要になります。私が知っている最も正確なものはQueryPerformanceCounterです。 Googleで詳細を確認してください。以下をクラスにプッシュして、CTimer sayと呼びます。その後、インスタンスをグローバルに作成して、.StartCounter.TimeElapsedを呼び出すだけです。

Option Explicit

Private Type LARGE_INTEGER
    lowpart As Long
    highpart As Long
End Type

Private Declare Function QueryPerformanceCounter Lib "kernel32" (lpPerformanceCount As LARGE_INTEGER) As Long
Private Declare Function QueryPerformanceFrequency Lib "kernel32" (lpFrequency As LARGE_INTEGER) As Long

Private m_CounterStart As LARGE_INTEGER
Private m_CounterEnd As LARGE_INTEGER
Private m_crFrequency As Double

Private Const TWO_32 = 4294967296# ' = 256# * 256# * 256# * 256#

Private Function LI2Double(LI As LARGE_INTEGER) As Double
Dim Low As Double
    Low = LI.lowpart
    If Low < 0 Then
        Low = Low + TWO_32
    End If
    LI2Double = LI.highpart * TWO_32 + Low
End Function

Private Sub Class_Initialize()
Dim PerfFrequency As LARGE_INTEGER
    QueryPerformanceFrequency PerfFrequency
    m_crFrequency = LI2Double(PerfFrequency)
End Sub

Public Sub StartCounter()
    QueryPerformanceCounter m_CounterStart
End Sub

Property Get TimeElapsed() As Double
Dim crStart As Double
Dim crStop As Double
    QueryPerformanceCounter m_CounterEnd
    crStart = LI2Double(m_CounterStart)
    crStop = LI2Double(m_CounterEnd)
    TimeElapsed = 1000# * (crStop - crStart) / m_crFrequency
End Property
78
Mike Woodhouse

VBAのタイマー機能は、午前0時から1/100秒までの経過秒数を示します。

Dim t as single
t = Timer
'code
MsgBox Timer - t
44
dbb

ストップウォッチのように時間を返そうとする場合は、システムの起動からの時間をミリ秒単位で返す次のAPIを使用できます。

Public Declare Function GetTickCount Lib "kernel32.dll" () As Long
Sub testTimer()
Dim t As Long
t = GetTickCount

For i = 1 To 1000000
a = a + 1
Next

MsgBox GetTickCount - t, , "Milliseconds"
End Sub

http://www.pcreview.co.uk/forums/grab-time-milliseconds-included-vba-t994765.html (winmm.dllのtimeGetTimeが機能せず、QueryPerformanceCounterが必要なタスクには複雑すぎる)

29
Kodak

Newbeeの場合、これらのリンクは、時間を監視するすべてのサブの自動プロファイリングを行う方法を説明しています。

http://www.nullskull.com/a/1602/profiling-and-optimizing-vba.aspx

http://sites.mcpher.com/share/Home/excelquirks/optimizationlink procProfiler.Zipを参照 http://sites.mcpher.com/share/Home/excelquirks/downlable -items

4
miodf

長年にわたってミリ秒の精度を得るために、winmm.dllのtimeGetTimeに基づくソリューションを使用してきました。 http://www.aboutvb.de/kom/artikel/komstopwatch.htm を参照してください

この記事はドイツ語ですが、ダウンロードのコード(dll関数呼び出しをラップするVBAクラス)は、記事を読むことなく使用して理解できるほど単純です。

2
Tom Juergens